#!/bin/sh

awk '
/^\.so/ {
	system("cat " $2)
	next
}
{
	print
}
' $* | awk '
BEGIN {
	endtag = ""
	title = 0
}

/^\./ {
	if(endtag != "" && $1 !~ "\.ft") {
		print endtag
		endtag = ""
	}
	if(title) {
		print "<H1><center>" titletext "</center></H1>"
		print "<hr>"
		title = 0
	}
	if($1 ~ "\.TL") {
		print "<TITLE>"
		endtag = "</TITLE>"
		title = 1
	} else if($1 ~ "\.\\\\\"") {
		if($2 == "HTML") {
			for(i=3; i <= NF; i++)
				printf("%s ", $i)
			printf "\n"
			next
		}
		print $0
	} else if($1 ~ "\.(sp|br)") {
		print "<br>"
	} else if($1 ~ "\.ce") {
		print "<center>"
		endtag = "</center>"
	} else if($1 ~ "\.bp") {
		print "<hr>"
	} else if($1 ~ "\.ft") {
		if($2 == "I") {
			print "<i>"
			endfont = "</i>"
		} else if($2 == "B") {
			print "<b>"
			endfont = "</b>"
		} else if($2 == "") {
			print endfont
			if(endtag != "") {
				print endtag
				endtag = ""
			}
		}
	} else if($1 ~ "\.PP") {
		print "<p>"
		endtag = "</p>"
	} else if($1 ~ "\.IP") {
		print "<p>"
		endtag = "</p>"
	} else if($1 ~ "\.SH") {
		print "<H3>"
		endtag = "</H3>"
	}
	next
}
{
	if(title)
		titletext = $0
	print
}'